set m=Unknown error

@echo ****************** CLEAN CLIENT/DOCS OUTPUT FOLDERS **********
rmdir c:\data\code\raven\server\AyaNova\wwwroot /s/q
mkdir c:\data\code\raven\server\AyaNova\wwwroot


@echo ******************** BUILD DOCS ******************************
cd c:\data\code\raven\docs\8.0\ayanova
mkdocs build
IF %ERRORLEVEL% NEQ 0 (
set m=DOCS FAILED TO BUILD
goto FAIL
)


@echo ******************** BUILD CLIENT ****************************
cd c:\data\code\raven-client\ayanova
call npm run build
IF %ERRORLEVEL% NEQ 0 (
set m=CLIENT FAILED TO BUILD
goto FAIL
)
xcopy c:\data\code\raven-client\ayanova\dist\* C:\data\code\raven\server\AyaNova\wwwroot\ /e
IF %ERRORLEVEL% NEQ 0 (
set m=CLIENT FAILED TO COPY
goto FAIL
)

@echo ******************** BUILD LINUX DOCKER **********************
rmdir C:\data\code\raven\dist\docker\linux-x64\ayanovadocker\files /s/q
mkdir C:\data\code\raven\dist\docker\linux-x64\ayanovadocker\files
cd C:\data\code\raven\server\AyaNova\
dotnet publish -o C:\data\code\raven\dist\docker\linux-x64\ayanovadocker\files\ -c Release -r linux-x64  --no-self-contained
IF %ERRORLEVEL% NEQ 0 (
set m=BUILD LINUX DOCKER FAILED
goto FAIL
)

@echo ************** BUILD WINDOWS STANDALONE SERVER ***********************
rmdir C:\data\code\raven\dist\win-x64\ayanova\standalone /s/q
mkdir C:\data\code\raven\dist\win-x64\ayanova\standalone
cd C:\data\code\raven\server\AyaNova\
dotnet publish -c Release -o C:\data\code\raven\dist\win-x64\ayanova\standalone\  -r win-x64 --self-contained
IF %ERRORLEVEL% NEQ 0 (
set m=BUILD WINDOWS STANDALONE FAILED
goto FAIL
)

@echo ******** BUILD WINDOWS FRAMEWORK-DEPENDENT SERVER ************
rmdir C:\data\code\raven\dist\win-x64\ayanova\framework-dependent /s/q
mkdir C:\data\code\raven\dist\win-x64\ayanova\framework-dependent
cd C:\data\code\raven\server\AyaNova\
dotnet publish -c Release -o C:\data\code\raven\dist\win-x64\ayanova\framework-dependent\  -r win-x64 --no-self-contained
IF %ERRORLEVEL% NEQ 0 (
set m=BUILD WINDOWS FRAMEWORK-DEPENDENT FAILED
goto FAIL
)

@echo ******************** BUILD LAUNCHER **************************
rmdir C:\data\code\raven\dist\win-x64\launcher /s/q
mkdir C:\data\code\raven\dist\win-x64\launcher
cd C:\data\code\raven-launcher\
dotnet publish -c Release -o C:\data\code\raven\dist\win-x64\launcher\  -r win-x64 --self-contained
IF %ERRORLEVEL% NEQ 0 (
set m=BUILD LAUNCHER FAILED
goto FAIL
)

@echo ************* BUILD STANDALONE INSTALLER *********************
"C:\Program Files (x86)\Inno Setup 6\ISCC.exe" C:\data\code\raven\dist\install\windows\x64\standalone.iss
IF %ERRORLEVEL% NEQ 0 (
set m=BUILD STANDALONE INSTALLER FAILED
goto FAIL
)

@echo ************* BUILD LAN INSTALLER *********************
"C:\Program Files (x86)\Inno Setup 6\ISCC.exe" C:\data\code\raven\dist\install\windows\x64\lan.iss
IF %ERRORLEVEL% NEQ 0 (
set m=BUILD LAN INSTALLER FAILED
goto FAIL
)


::Completed processing without error
goto OK

::------------------------
:FAIL
echo.
echo.
echo.
echo.
echo.
echo Error:
echo %m%
pause
goto DONE

::------------------------
:OK
echo.
echo.
echo.
echo.
echo.
@echo Completed without error
pause


:DONE